uses VBScript_RegExp_55_TLB;

procedure TForm1.Button1Click(Sender: TObject);
var
  Regexp: TRegExp;
  Matched: boolean;
begin
  Regexp := TRegExp.Create(nil);
  try
    Regexp.IgnoreCase := True;      //大文字小文字を区別しない
    Regexp.Pattern := '^delphi';    //正規表現パターン
    Matched := Regexp.Test('Delphi is the product of Borland.');   //テスト
    ShowMessage(BoolToStr(Matched, True));
  finally
    Regexp.Free;
  end;
end;

uses VBScript_RegExp_55_TLB;

procedure TForm1.Button2Click(Sender: TObject);
var
  Regexp: TRegExp;
  Rep: string;
begin
  Regexp := TRegExp.Create(nil);
  try
    Regexp.Global := True;      //全部を対象とする
    Regexp.Pattern := '明日';   //正規表現パターン
    Rep := Regexp.Replace('明日は明日の風が吹く', 'あした');    //置換
    ShowMessage(Rep);
  finally
    Regexp.Free;
  end;
end;

• TRegExp.Replaceの返り値はWideString、つまりUnicodeです。そのためLengthで文字数をカウントすると、上記の例では12となります。通常のstringと同じように扱いたい場合は、返り値を入れる変数をstringで宣言します。そこへ代入すれば、自動的にキャストされます。上記の例だとLength(Rep)は24となります（バイトでのカウント）。
• TRegExp.Replaceの第2引数(replaceVar)はOleVariant型です。そのため、文字列以外に数値もそのまま指定することが出来ます。つまり数値で置換したい場合でもわざわざIntToStrなどを行う必要はありません。

uses VBScript_RegExp_55_TLB;

procedure TForm1.Button3Click(Sender: TObject);
var
  Regexp: TRegExp;
  Source: string;
  Rep: string;
begin
  Regexp := TRegExp.Create(nil);
  try
    Regexp.IgnoreCase := True;
    Regexp.Pattern := '<a\s+href=["'']*([^>"'']*)["'']*>(.*?)</a>';
    Source := '<a href=""http://www.yahoo.co.jp/"">Yahoo! Japan</a>';
    Rep := Regexp.Replace(Source, 'URL=$1, Title=$2');
    ShowMessage(Rep);
  finally
    Regexp.Free;
  end;
end;

• 後方参照を使った置換の例です。正規表現ではカッコ（）でくくった部分が後方参照となり、マッチした文字列を抽出することが出来ます。抽出した文字列は、前から順に「$1..$2..$n」として参照できます。

uses VBScript_RegExp_55_TLB;

procedure TForm1.Button4Click(Sender: TObject);
const
  Pattern = '<a\s+href=["'']*([^>"'']*)["'']*>(.*?)</a>';
  Source = '<a href="http://www.borland.co.jp/">日本ボーランド</a><a href="http://www.google.co.jp/">Google</a>';
var
  Regex: TRegExp;
  MatCol: MatchCollection;
  Mat: Match;
  SubMat: SubMatches;
  i: integer;
begin
  Regexp := TRegExp.Create(nil);
  try
    Regex.IgnoreCase := True;      //大文字小文字を区別しない
    Regex.Global := True;          //全部を対象とする
    Regex.Pattern := Pattern;      //正規表現パターン
    MatCol := Regex.Execute(Source) as MatchCollection;    //実行
    
    for i := 0 to MatCol.Count - 1 do
    begin
      Mat := MatCol.Item[i] as Match;
      SubMat := Mat.SubMatches as SubMatches;
      Memo1.Lines.Add(Mat.Value);       //マッチした文字列
      Memo1.Lines.Add(SubMat.Item[0]);  //後方参照の文字列
      Memo1.Lines.Add(SubMat.Item[1]);
    end;
  finally
    Regexp.Free;
  end;
end;

• 上記の例は、aタグからアドレスとリンク先名を抽出するサンプルです。
  正規表現ではカッコ（）でくくった部分が後方参照となり、マッチした文字列を抽出することが出来ます。
• as演算子を使って型キャストしている個所がいくつかありますが、これは宣言されている型がIDispatchなのでそのままでは使用できず、適切な型にキャストする必要があるためです。
• GlobalプロパティをTrueにしてExecuteすると、正規表現にマッチする文字列が複数ある場合は、MatchCollectionに複数の結果が返ってきます。上記例では「日本ボーランド」と「google」のリンクが両方ともマッチするので、MatchCollectionには2つのデータが入っています。
• MatchCollectionに入っているそれぞれの値は、MatchCollection.Item[]で取得でき、これはMatchクラスです。正規表現にマッチした文字列の結果が入っています。
• MatchクラスのSubMatchesプロパティには、後方参照の結果が入っていて、Match.Item[]で取得できます。